Программа выгрузки и загрузки данных из таблиц, посредством текстового файла

Выкладываю исходный код программы которая позволяет загружать и выгружать данные из таблиц в текстовый файл

выгрузка, загрузка данных, загрузка файла,экспорт,export,import

  1. *&---------------------------------------------------------------------*
  2. *& Report  ZBC_IMP_EXP_TABLE
  3. *&
  4. *&---------------------------------------------------------------------*
  5. *&
  6. *&
  7. *&---------------------------------------------------------------------*
  8.  
  9. report  zbc_imp_exp_table line-size 80
  10.                 line-count 65
  11.                 no standard page heading..
  12. type-pools: abap.
  13.  
  14. constants: gc_separator      type char3   value '#~#',
  15.            gc_name_rec       type char2   value 'A0',
  16.            gc_header_rec     type char2   value 'A1',
  17.            gc_record_rec     type char2   value 'A2',
  18.            gc_0d_replace     type char6   value '#~0D~#',  " Чем заменить перевод строки
  19.            gc_0a_replace     type char6   value '#~0A~#'.  " Чем заменить перевод строки
  20.  
  21. tables: dd02l.
  22.  
  23. types: begin of lty_tabline,
  24.          rectype        type char2,   " Тип записи файла
  25.          line           type string,  " Строка файла, поля разделены разделителями
  26.        end of lty_tabline,
  27.        begin of lty_fieldname,
  28.          fieldname   type dd03l-fieldname,
  29.        end of lty_fieldname.
  30.  
  31. types: lty_t_tabline     type table of lty_tabline,
  32.        lty_t_fieldname   type table of lty_fieldname.
  33.  
  34. parameters: p_file    type text255 obligatory.
  35. select-options: s_tables   for dd02l-tabname.
  36. parameters: p_exp     type c radiobutton group 1 default 'X' user-command exp,
  37.             p_imp     type c radiobutton group 1,
  38.             p_del     type c as checkbox default ' '.
  39.  
  40. selection-screen begin of block badd with frame title text-add.
  41. parameters: p_cond1   type text50 modif id exp,
  42.             p_cond2   type text50 modif id exp,
  43.             p_cond3   type text50 modif id exp.
  44. selection-screen end of block badd.
  45.  
  46. *----------------------------------------------------------------------
  47. at selection-screen on value-request for p_file.
  48.   perform open_file_name changing p_file.
  49.  
  50. *----------------------------------------------------------------------
  51. at user-command.
  52.   case sy-ucomm.
  53.     when 'EXP'.
  54.       perform output.
  55.   endcase.
  56.  
  57. at selection-screen output.
  58.   perform output.
  59.  
  60. *----------------------------------------------------------------------
  61. start-of-selection.
  62.   if p_exp = abap_true.
  63.     perform main_export.
  64.   else.
  65.     perform main_import.
  66.   endif.
  67.  
  68. *&---------------------------------------------------------------------*
  69. *&      Form  output
  70. *&---------------------------------------------------------------------*
  71. *       text
  72. *----------------------------------------------------------------------*
  73. form output.
  74.   loop at screen.
  75.     if screen-name = 'P_DEL'.
  76.       if p_exp = abap_true.
  77.         screen-input = 0.
  78.       else.
  79.         screen-input = 1.
  80.       endif.
  81.     endif.
  82.  
  83.     if screen-group1 = 'EXP'.
  84.       if p_exp = abap_true.
  85.         screen-input = 1.
  86.       else.
  87.         screen-input = 0.
  88.       endif.
  89.     endif.
  90.  
  91.     modify screen.
  92.   endloop.
  93. endform.                    "output
  94.  
  95. *&---------------------------------------------------------------------*
  96. *&      Form  export_table_to_file
  97. *&---------------------------------------------------------------------*
  98. *       text
  99. *----------------------------------------------------------------------*
  100. *  -->  p1        text
  101. *  <--  p2        text
  102. *----------------------------------------------------------------------*
  103. form add_table_to_file using value(u_tabname)  type dd02l-tabname
  104.                        changing ct_contents    type lty_t_tabline
  105.                                 value(c_rc)    type sysubrc.
  106.  
  107.   data: lt_fields         type table of lty_fieldname,
  108.         lr_data           type ref to data,
  109.         lv_value          type string,
  110.         lv_tabix          type sy-tabix,
  111.         lv_dummy          type bapiret2-message.
  112.  
  113.   field-symbols: <ls_tabline>        type lty_tabline,
  114.                  <ls_fieldname>      type lty_fieldname,
  115.                  <lt_table>          type table,
  116.                  <ls_line>           type any,
  117.                  <lv_value>          type any.
  118.  
  119. * Check if table exists
  120.   select single tabname
  121.     into u_tabname
  122.     from dd02l
  123.     where tabname  = u_tabname
  124.       and tabclass = 'TRANSP'.
  125.  
  126.   if sy-subrc <> 0.
  127.     message e000(clhp) with 'Не найдена в системе таблица'(001) u_tabname
  128.       into lv_dummy.
  129.     c_rc = 1.
  130.     return.
  131.   endif.
  132.  
  133. * Заголовок - имя таблицы
  134.   append initial line to ct_contents assigning <ls_tabline>.
  135.   <ls_tabline>-rectype = gc_name_rec.
  136.   <ls_tabline>-line    = u_tabname.
  137.  
  138. * Заголовок таблицы (имена полей)
  139.   perform get_table_fields using u_tabname changing lt_fields.
  140.  
  141.   append initial line to ct_contents assigning <ls_tabline>.
  142.   <ls_tabline>-rectype = gc_header_rec.
  143.  
  144.   loop at lt_fields assigning <ls_fieldname>.
  145.  
  146.     if sy-tabix > 1.
  147.       concatenate <ls_tabline>-line gc_separator into <ls_tabline>-line.
  148.     endif.
  149.  
  150.     concatenate <ls_tabline>-line <ls_fieldname>-fieldname into <ls_tabline>-line.
  151.   endloop.
  152.  
  153. * Строки таблицы
  154.   create data lr_data type table of (u_tabname).
  155.   assign lr_data->* to <lt_table>.
  156.  
  157.   " Применяем подходящие условия
  158.   do 1 times.
  159.  
  160.     if p_cond1 is not initial.
  161.       try.
  162.  
  163.           select *
  164.             from (u_tabname)
  165.             into table <lt_table>
  166.             where (p_cond1).
  167.  
  168.           exit.
  169.         catch cx_sy_dynamic_osql_semantics.
  170.       endtry.
  171.     endif.
  172.  
  173.     if p_cond2 is not initial.
  174.       try.
  175.  
  176.           select *
  177.             from (u_tabname)
  178.             into table <lt_table>
  179.             where (p_cond2).
  180.  
  181.           exit.
  182.         catch cx_sy_dynamic_osql_semantics.
  183.       endtry.
  184.     endif.
  185.  
  186.     if p_cond3 is not initial.
  187.       try.
  188.  
  189.           select *
  190.             from (u_tabname)
  191.             into table <lt_table>
  192.             where (p_cond3).
  193.  
  194.           exit.
  195.         catch cx_sy_dynamic_osql_semantics.
  196.       endtry.
  197.     endif.
  198.  
  199.     select *
  200.       from (u_tabname)
  201.       into table <lt_table>.
  202.   enddo.
  203.  
  204.   loop at <lt_table> assigning <ls_line>.
  205.  
  206.     append initial line to ct_contents assigning <ls_tabline>.
  207.     <ls_tabline>-rectype = gc_record_rec.
  208.  
  209.     loop at lt_fields assigning <ls_fieldname>.
  210.  
  211.       lv_tabix = sy-tabix.
  212.  
  213.       assign component <ls_fieldname>-fieldname of structure <ls_line> to <lv_value>.
  214.       if sy-subrc = 0.
  215.         lv_value = <lv_value>.
  216.       else.
  217.         clear lv_value.
  218.       endif.
  219.  
  220.       replace all occurrences of cl_abap_char_utilities=>cr_lf(1) in lv_value
  221.         with gc_0d_replace.
  222.  
  223.       replace all occurrences of cl_abap_char_utilities=>cr_lf+1(1) in lv_value
  224.         with gc_0a_replace.
  225.  
  226.       if lv_tabix > 1.
  227.         concatenate <ls_tabline>-line gc_separator into <ls_tabline>-line.
  228.       endif.
  229.  
  230.       concatenate <ls_tabline>-line lv_value into <ls_tabline>-line.
  231.     endloop.
  232.   endloop.
  233. endform.                    " export_table_to_file
  234. *&---------------------------------------------------------------------*
  235. *&      Form  get_table_fields
  236. *&---------------------------------------------------------------------*
  237. *       Возвращает имена полей таблицы без mandt
  238. *----------------------------------------------------------------------*
  239. *  -->  p1        text
  240. *  <--  p2        text
  241. *----------------------------------------------------------------------*
  242. form get_table_fields using value(u_tabname)  type dd02l-tabname
  243.                       changing ct_fields      type lty_t_fieldname.
  244.  
  245.   select fieldname
  246.     from dd03l
  247.     into table ct_fields
  248.     where tabname   = u_tabname
  249.       and precfield = space       " Исключаем include
  250.       and domname   <> 'MANDT'.   " Исключаем мандант
  251. endform.                    " get_table_fields
  252. *&---------------------------------------------------------------------*
  253. *&      Form  get_all_tabnames_from_file
  254. *&---------------------------------------------------------------------*
  255. *       Возвращает список таблиц, которые есть в файле
  256. *----------------------------------------------------------------------*
  257. *  -->  p1        text
  258. *  <--  p2        text
  259. *----------------------------------------------------------------------*
  260. form get_all_tabnames_from_file using    ut_content   type lty_t_tabline
  261.                                 changing ct_names     type string_table.
  262.  
  263.   field-symbols: <ls_tabline>     type lty_tabline.
  264.  
  265.   refresh ct_names[].
  266.  
  267.   loop at ut_content assigning <ls_tabline>
  268.     where rectype = gc_name_rec.
  269.  
  270.     append <ls_tabline>-line to ct_names.
  271.   endloop.
  272. endform.                    " get_all_tabnames_from_file
  273. *&---------------------------------------------------------------------*
  274. *&      Form  check_table_structure
  275. *&---------------------------------------------------------------------*
  276. *       Выполняет проверку структуры таблицы, возвращает флаг
  277. *       успешности-неуспешности и список ошибок если неуспех
  278. *----------------------------------------------------------------------*
  279. *  -->  p1        text
  280. *  <--  p2        text
  281. *----------------------------------------------------------------------*
  282. form check_table_structure using value(u_tabname)    type dd02l-tabname
  283.                                  ut_content          type lty_t_tabline
  284.                            changing ct_return        type bapiret2_t
  285.                                     value(c_rc)      type sysubrc.
  286.  
  287.   data: lv_index              type sy-tabix,
  288.         lv_text               type string,
  289.         lt_fields_file        type table of lty_fieldname,
  290.         lt_fields_sap         type table of lty_fieldname,
  291.         lv_num_fields_sap     type i,
  292.         lv_num_fields_file    type i,
  293.         lv_not_found          type wdy_boolean.
  294.  
  295.   field-symbols: <ls_tabline>      type lty_tabline,
  296.                  <ls_field_file>   type lty_fieldname,
  297.                  <ls_field_sap>    type lty_fieldname.
  298.  
  299. * Find the table record
  300.   read table ut_content with key rectype = gc_name_rec
  301.                                  line    = u_tabname
  302.                                  transporting no fields.
  303.  
  304.   if sy-subrc <> 0.
  305.  
  306.     concatenate 'Таблица'(002) u_tabname 'не найдена в файле'(003) into lv_text separated by space.
  307.     perform msg_to_ret2_string using lv_text 'E' changing ct_return[].
  308.     c_rc = 1.
  309.     return.
  310.   endif.
  311.  
  312. * Look for header description line to compare to the database state
  313.   lv_index = sy-tabix.
  314.   lv_index = lv_index + 1.
  315.  
  316.   perform get_first_header_after_line
  317.               using
  318.                   u_tabname
  319.                   ut_content
  320.                   lv_index
  321.               changing
  322.                   lt_fields_file[]
  323.                   c_rc.
  324.  
  325.   if c_rc <> 0.
  326.     perform msg_to_ret2_string using lv_text 'E' changing ct_return[].
  327.     return.
  328.   endif.
  329.  
  330. * Get fields list from database and perform the comparison
  331.   perform get_table_fields using u_tabname changing lt_fields_sap.
  332.  
  333.   describe table lt_fields_sap lines lv_num_fields_sap.
  334.   describe table lt_fields_file lines lv_num_fields_file.
  335.  
  336.   loop at lt_fields_file assigning <ls_field_file>.
  337.  
  338.     lv_index = sy-tabix.
  339.     lv_not_found = abap_false.
  340.  
  341.     unassign <ls_field_sap>.
  342.     if lv_index <= lv_num_fields_sap.
  343.       read table lt_fields_sap index sy-tabix assigning <ls_field_sap>.
  344.     endif.
  345.  
  346.     if <ls_field_sap> is assigned.
  347.       if <ls_field_sap>-fieldname <> <ls_field_file>-fieldname.
  348.         lv_not_found = abap_true.
  349.       endif.
  350.     else.
  351.       lv_not_found = abap_true.
  352.     endif.
  353.  
  354.     if lv_not_found = abap_true.
  355.       concatenate 'В SAP отсутствует (или находится в другой позиции) поле'(004)
  356.         <ls_field_file>-fieldname 'таблицы'(005) u_tabname ', имеющееся в файле'(006)
  357.         into lv_text separated by space.
  358.       perform msg_to_ret2_string using lv_text 'E' changing ct_return[].
  359.       c_rc = 1.
  360.     endif.
  361.   endloop.
  362.  
  363.   if lv_num_fields_sap <> lv_num_fields_file.
  364.     loop at lt_fields_sap assigning <ls_field_sap>.
  365.  
  366.       read table lt_fields_file with key fieldname = <ls_field_sap>-fieldname
  367.         transporting no fields.
  368.       if sy-subrc <> 0.
  369.         concatenate 'В файле отсутствует поле'(007) <ls_field_sap>-fieldname
  370.           'таблицы'(005) u_tabname ', имеющееся в SAP'(008) into lv_text separated by space.
  371.         perform msg_to_ret2_string using lv_text 'E' changing ct_return[].
  372.         c_rc = 1.
  373.       endif.
  374.     endloop.
  375.   endif.
  376. endform.                    " check_table_structure
  377. *&---------------------------------------------------------------------*
  378. *&      Form  modify_dbtab_from_file
  379. *&---------------------------------------------------------------------*
  380. *       Выполняет модицикацию таблицы из файла
  381. *----------------------------------------------------------------------*
  382. *  -->  p1        text
  383. *  <--  p2        text
  384. *----------------------------------------------------------------------*
  385. form modify_dbtab_from_file using value(u_tabname)     type dd02l-tabname
  386.                                   ut_content           type lty_t_tabline
  387.                                   value(u_delete)      type wdy_boolean
  388.                             changing value(c_rc)       type sysubrc.
  389.  
  390.   data: lv_dummy           type bapiret2-message,
  391.         lv_tabix           type sy-tabix,
  392.         lr_data            type ref to data,
  393.         lt_values          type table of string,
  394.         lv_value           type string,
  395.         lv_clidep          type dd02l-clidep.
  396.  
  397.   field-symbols: <ls_tabline>       type lty_tabline,
  398.                  <ls_dbtab_line>    type any,
  399.                  <lv_value>         type any,
  400.                  <ls_fieldname>     type lty_fieldname.
  401.  
  402. * Find the table record
  403.   read table ut_content with key rectype = gc_name_rec
  404.                                  line    = u_tabname
  405.                                  transporting no fields.
  406.  
  407.   if sy-subrc <> 0.
  408.     message e000(clhp) with 'Таблица'(002) u_tabname 'не найдена в файле'(003)
  409.       into lv_dummy.
  410.     c_rc = 1.
  411.     return.
  412.   endif.
  413.  
  414.   lv_tabix = sy-tabix + 1.
  415.  
  416.   select single clidep
  417.     into lv_clidep
  418.     from dd02l
  419.     where tabname = u_tabname
  420.       and tabclass = 'TRANSP'.
  421.  
  422.   create data lr_data type (u_tabname).
  423.   assign lr_data->* to <ls_dbtab_line>.
  424.  
  425.   if u_delete = abap_true.
  426.     delete from (u_tabname).                            "#EC CI_NOWHERE
  427.   endif.
  428.  
  429.   loop at ut_content assigning <ls_tabline>
  430.     from lv_tabix.
  431.     "WHERE rectype = gc_record_rec.
  432.  
  433.     " Началась следующая таблица - выходим
  434.     if <ls_tabline>-rectype = gc_name_rec.
  435.       exit.
  436.     endif.
  437.  
  438.     check <ls_tabline>-rectype = gc_record_rec.
  439.  
  440.     split <ls_tabline>-line at gc_separator into table lt_values.
  441.  
  442.     loop at lt_values into lv_value.
  443.  
  444.       lv_tabix = sy-tabix.
  445.  
  446.       " Если таблица зависима от манданта, то номер поля будет на 1 больше
  447.       if lv_clidep = abap_true.
  448.         lv_tabix = lv_tabix + 1.
  449.       endif.
  450.  
  451.       assign component lv_tabix of structure <ls_dbtab_line> to <lv_value>.
  452.       if sy-subrc = 0.
  453.         <lv_value> = lv_value.
  454.       endif.
  455.     endloop.
  456.  
  457.     modify (u_tabname) from <ls_dbtab_line>.
  458.   endloop.
  459. endform.                    " modify_dbtab_from_file
  460. *&---------------------------------------------------------------------*
  461. *&      Form  get_first_header_after_line
  462. *&---------------------------------------------------------------------*
  463. *       Технический код: возвращает поля первого заголовка файла
  464. *       в загруженном контенте после определенной строки этого файла
  465. *----------------------------------------------------------------------*
  466. *  -->  p1        text
  467. *  <--  p2        text
  468. *----------------------------------------------------------------------*
  469. form get_first_header_after_line using value(u_tabname)       type dd02l-tabname
  470.                                        ut_content             type lty_t_tabline
  471.                                        value(u_line_from)     type i
  472.                                  changing ct_header_fields    type lty_t_fieldname
  473.                                           value(c_rc)         type sysubrc.
  474.  
  475.   data: lv_dummy        type bapiret2-message.
  476.  
  477.   field-symbols: <ls_tabline>     type lty_tabline.
  478.  
  479.   loop at ut_content assigning <ls_tabline>
  480.     from u_line_from
  481.     where rectype = gc_header_rec.
  482.  
  483.     exit.
  484.   endloop.
  485.  
  486.   if sy-subrc <> 0.
  487.     message e000(clhp) with 'Для таблицы'(009) u_tabname
  488.       'не найдена строка заголовка в файле'(010) into lv_dummy.
  489.     c_rc = 1.
  490.     return.
  491.   endif.
  492.  
  493. * Parse the header string in order to get field list from it
  494.   split <ls_tabline>-line at gc_separator into table ct_header_fields.
  495. endform.                    " get_first_header_after_line
  496. *&---------------------------------------------------------------------*
  497. *&      Form  load_contents_from_file
  498. *&---------------------------------------------------------------------*
  499. *       Загружает файл с диска во внутреннюю таблицу
  500. *----------------------------------------------------------------------*
  501. *  -->  p1        text
  502. *  <--  p2        text
  503. *----------------------------------------------------------------------*
  504. form load_contents_from_file using u_filename
  505.                              changing ct_content     type lty_t_tabline
  506.                                       value(c_rc)    type sysubrc.
  507.  
  508.   data: begin of lt_data_tab occurs 0,
  509.           line(3000)    type c,
  510.         end of lt_data_tab.
  511.  
  512.   data: lv_filename           type string,
  513.         lv_contents           type string,
  514.         lt_lines              type table of string,
  515.         lv_text               type string.
  516.  
  517.   field-symbols: <ls_tabline>        type lty_tabline.
  518.  
  519.   lv_filename = u_filename.
  520.  
  521.   refresh ct_content[].
  522.  
  523.   call method cl_gui_frontend_services=>gui_upload
  524.     exporting
  525.       filename                = lv_filename
  526.       read_by_line            = abap_false
  527.     changing
  528.       data_tab                = lt_data_tab[]
  529.     exceptions
  530.       file_open_error         = 1
  531.       file_read_error         = 2
  532.       no_batch                = 3
  533.       gui_refuse_filetransfer = 4
  534.       invalid_type            = 5
  535.       no_authority            = 6
  536.       unknown_error           = 7
  537.       bad_data_format         = 8
  538.       header_not_allowed      = 9
  539.       separator_not_allowed   = 10
  540.       header_too_long         = 11
  541.       unknown_dp_error        = 12
  542.       access_denied           = 13
  543.       dp_out_of_memory        = 14
  544.       disk_full               = 15
  545.       dp_timeout              = 16
  546.       not_supported_by_gui    = 17
  547.       error_no_gui            = 18
  548.       others                  = 19.
  549.  
  550.   c_rc = sy-subrc.
  551.  
  552.   if c_rc <> 0.
  553.     return.
  554.   endif.
  555.  
  556.   loop at lt_data_tab.
  557.     concatenate lv_contents lt_data_tab into lv_contents.
  558.   endloop.
  559.  
  560.   split lv_contents at cl_abap_char_utilities=>cr_lf into table lt_lines.
  561.  
  562. * Каждая строка файла содержит вид записи (2 символа), разделитель, а затем
  563. * уже информацию в зависимости от вида записи
  564.   loop at lt_lines into lv_text.
  565.  
  566.     check lv_text is not initial.
  567.     check strlen( lv_text ) >= 5.
  568.  
  569.     append initial line to ct_content assigning <ls_tabline>.
  570.     split lv_text at gc_separator into <ls_tabline>-rectype <ls_tabline>-line.
  571.  
  572.     replace all occurrences of gc_0d_replace in <ls_tabline>-line
  573.       with cl_abap_char_utilities=>cr_lf(1).
  574.  
  575.     replace all occurrences of gc_0a_replace in <ls_tabline>-line
  576.       with cl_abap_char_utilities=>cr_lf+1(1).
  577.   endloop.
  578. endform.                    " load_contents_from_file
  579. *&---------------------------------------------------------------------*
  580. *&      Form  save_contents_to_file
  581. *&---------------------------------------------------------------------*
  582. *       Сохраняет содержимое файла из внутренней таблицы на диск
  583. *----------------------------------------------------------------------*
  584. *  -->  p1        text
  585. *  <--  p2        text
  586. *----------------------------------------------------------------------*
  587. form save_contents_to_file using u_filename
  588.                                  ut_content         type lty_t_tabline
  589.                            changing value(c_rc)     type sysubrc.
  590.  
  591.   data: begin of lt_data_tab occurs 0,
  592.           line(3000)    type c,
  593.         end of lt_data_tab.
  594.  
  595.   data: lv_string            type string,
  596.         lv_lines             type i,
  597.         lv_filename          type string.
  598.  
  599.   field-symbols: <ls_tabline>           type lty_tabline.
  600.  
  601.   lv_filename = u_filename.
  602.  
  603.   lv_lines = lines( ut_content ).
  604.  
  605.   loop at ut_content assigning <ls_tabline>.
  606.  
  607.     if lv_string is not initial.
  608.       concatenate lv_string cl_abap_char_utilities=>cr_lf into lv_string.
  609.     endif.
  610.  
  611.     concatenate lv_string <ls_tabline>-rectype gc_separator <ls_tabline>-line
  612.       into lv_string.
  613.   endloop.
  614.  
  615.   call function 'SCMS_STRING_TO_FTEXT'
  616.     exporting
  617.       text      = lv_string
  618.     tables
  619.       ftext_tab = lt_data_tab[].
  620.  
  621.   call method cl_gui_frontend_services=>gui_download
  622.     exporting
  623.       filename                 = lv_filename
  624.       write_lf                 = abap_false
  625.       write_lf_after_last_line = abap_false
  626.     changing
  627.       data_tab                 = lt_data_tab[]      "trunc_trailing_blanks = abap_true
  628.     exceptions
  629.       file_write_error         = 1
  630.       no_batch                 = 2
  631.       gui_refuse_filetransfer  = 3
  632.       invalid_type             = 4
  633.       no_authority             = 5
  634.       unknown_error            = 6
  635.       header_not_allowed       = 7
  636.       separator_not_allowed    = 8
  637.       filesize_not_allowed     = 9
  638.       header_too_long          = 10
  639.       dp_error_create          = 11
  640.       dp_error_send            = 12
  641.       dp_error_write           = 13
  642.       unknown_dp_error         = 14
  643.       access_denied            = 15
  644.       dp_out_of_memory         = 16
  645.       disk_full                = 17
  646.       dp_timeout               = 18
  647.       file_not_found           = 19
  648.       dataprovider_exception   = 20
  649.       control_flush_error      = 21
  650.       not_supported_by_gui     = 22
  651.       error_no_gui             = 23
  652.       others                   = 24.
  653.  
  654.   c_rc = sy-subrc.
  655. endform.                    " save_contents_to_file
  656.  
  657. *&---------------------------------------------------------------------*
  658. *&      Form  open_file_name
  659. *&---------------------------------------------------------------------*
  660. *       text
  661. *----------------------------------------------------------------------*
  662. *      -->UC_FILE    text
  663. *----------------------------------------------------------------------*
  664. form open_file_name changing uc_file type c.
  665.  
  666.   data: lt_filetable  type filetable,
  667.         ld_str        type string,
  668.         ld_rc         type i.
  669.  
  670. * Отображаем стандартный диалог открытия файла
  671.   ld_str = 'Выберите файл для загрузки'(011).
  672.   call method cl_gui_frontend_services=>file_open_dialog
  673.     exporting
  674.       window_title   = ld_str
  675.       file_filter    = 'Text files|*.txt'
  676.       multiselection = ' '
  677.     changing
  678.       file_table     = lt_filetable[]
  679.       rc             = ld_rc.                               "#EC NOTEXT
  680.  
  681. * Записываем имя файла в параметр
  682.   if sy-subrc = 0.
  683.     read table lt_filetable index 1 into uc_file.
  684.   endif.
  685. endform.                    "open_file_name
  686. *&---------------------------------------------------------------------*
  687. *&      Form  main_export
  688. *&---------------------------------------------------------------------*
  689. *       Главная процедура, выполняющая экспорт
  690. *----------------------------------------------------------------------*
  691. *  -->  p1        text
  692. *  <--  p2        text
  693. *----------------------------------------------------------------------*
  694. form main_export.
  695.  
  696.   data: lt_contents        type table of lty_tabline,
  697.         lv_rc              type sysubrc,
  698.         lt_log             type table of bapiret2,
  699.         lv_text            type string.
  700.  
  701.   field-symbols: <ls_sel_table>   like line of s_tables.
  702.  
  703.   if s_tables[] is initial.
  704.     message e000(clhp) with 'Ни одной таблицы не выбрано'(012).
  705.   endif.
  706.  
  707. * Формируем файл на основе всех таблиц во внутренней таблице
  708.   loop at s_tables assigning <ls_sel_table>.
  709.  
  710.     concatenate 'Подготовка таблицы'(013) <ls_sel_table>-low into lv_text separated by space.
  711.     perform statusbar_message using 0 lv_text.
  712.  
  713.     perform add_table_to_file
  714.                 using
  715.                    <ls_sel_table>-low
  716.                 changing
  717.                    lt_contents[]
  718.                    lv_rc.
  719.  
  720.     if lv_rc <> 0.
  721.       perform log_msg changing lt_log[].
  722.       perform show_log using lt_log[].
  723.       return.
  724.     endif.
  725.   endloop.
  726.  
  727.   lv_text = 'Сохранение данных в файл'(014).
  728.   perform statusbar_message using 0 lv_text.
  729.  
  730. * Сохраняем сформированную таблицу в файл
  731.   perform save_contents_to_file
  732.               using
  733.                  p_file
  734.                  lt_contents[]
  735.               changing
  736.                   lv_rc.
  737.  
  738.   if lv_rc <> 0.
  739.     perform log_msg changing lt_log[].
  740.     perform show_log using lt_log[].
  741.     return.
  742.   endif.
  743.  
  744.   message s000(clhp) with 'Данные успешно выгружены в файл'(015) p_file.
  745. endform.                    " main_export
  746. *&---------------------------------------------------------------------*
  747. *&      Form  main_import
  748. *&---------------------------------------------------------------------*
  749. *       Главная процедура, выполняющая импорт
  750. *----------------------------------------------------------------------*
  751. *  -->  p1        text
  752. *  <--  p2        text
  753. *----------------------------------------------------------------------*
  754. form main_import.
  755.  
  756.   data: lt_contents          type table of lty_tabline,
  757.         lv_rc                type sysubrc,
  758.         lt_names             type table of string,
  759.         lv_name              type dd02l-tabname,
  760.         lt_log               type table of bapiret2,
  761.         lt_return            type table of bapiret2,
  762.         lv_global_rc         type sysubrc,
  763.         lv_text              type string,
  764.         lv_lines             type i,
  765.         lv_ans               type char1.
  766.  
  767.   lv_text = 'Загрузка данных'(016).
  768.   perform statusbar_message using 0 lv_text.
  769.  
  770. * Load file to internal table
  771.   perform load_contents_from_file
  772.               using
  773.                  p_file
  774.               changing
  775.                  lt_contents
  776.                  lv_rc.
  777.  
  778.   if lv_rc <> 0.
  779.     perform log_msg changing lt_log[].
  780.     perform show_log using lt_log[].
  781.     return.
  782.   endif.
  783.  
  784.   lv_text = 'Проверка данных'(017).
  785.   perform statusbar_message using 0 lv_text.
  786.  
  787. * List tables stored in file
  788.   perform get_all_tabnames_from_file
  789.               using
  790.                  lt_contents
  791.               changing
  792.                  lt_names.
  793.  
  794.   if lt_names[] is initial.
  795.     perform msg_to_ret2_string using 'В файле не найдено ни одной таблицы'(018) 'E' changing lt_log[].
  796.     perform show_log using lt_log[].
  797.     return.
  798.   endif.
  799.  
  800. * Check each table, table structure must match
  801.   loop at lt_names into lv_name.
  802.  
  803.     perform check_table_structure
  804.                 using
  805.                    lv_name
  806.                    lt_contents[]
  807.                 changing
  808.                    lt_return
  809.                    lv_rc.
  810.  
  811.     if lv_rc <> 0.
  812.       append lines of lt_return to lt_log.
  813.       lv_global_rc = lv_rc.
  814.     endif.
  815.   endloop.
  816.  
  817.   if lv_global_rc <> 0.
  818.     perform msg_to_ret2_string using 'При загрузке файла были ошибки'(019) 'E' changing lt_log[].
  819.     perform show_log using lt_log[].
  820.     return.
  821.   endif.
  822.  
  823. * Delete tables not matching the selection
  824.   loop at lt_names into lv_name.
  825.     if lv_name not in s_tables.
  826.       delete lt_names.
  827.     endif.
  828.   endloop.
  829.  
  830.   if lt_names[] is initial.
  831.     perform msg_to_ret2_string using 'Ни один из содержащихся в файле таблиц не подходит под критерии выбора, ничего не загружено'(020) 'W'
  832.           changing lt_log[].
  833.     perform show_log using lt_log[].
  834.     return.
  835.   endif.
  836.  
  837.   if lv_global_rc <> 0.
  838.     perform show_log using lt_log[].
  839.     return.
  840.   endif.
  841.  
  842. * Several user asks and dialogs
  843.   lv_lines = lines( lt_names ).
  844.   lv_text = lv_lines.
  845.   condense lv_text.
  846.   concatenate 'Всего из файла будет загружено'(022) lv_text 'таблиц. Продолжить загрузку?'(023)
  847.     into lv_text separated by space.
  848.  
  849.   call function 'POPUP_TO_CONFIRM'
  850.     exporting
  851. *     TITLEBAR                    = ' '
  852. *     DIAGNOSE_OBJECT             = ' '
  853.       text_question               = lv_text
  854. *     TEXT_BUTTON_1               = 'Ja'(001)
  855. *     ICON_BUTTON_1               = ' '
  856. *     TEXT_BUTTON_2               = 'Nein'(002)
  857. *     ICON_BUTTON_2               = ' '
  858. *     DEFAULT_BUTTON              = '1'
  859. *     DISPLAY_CANCEL_BUTTON       = 'X'
  860. *     USERDEFINED_F1_HELP         = ' '
  861. *     START_COLUMN                = 25
  862. *     START_ROW                   = 6
  863. *     POPUP_TYPE                  =
  864. *     IV_QUICKINFO_BUTTON_1       = ' '
  865. *     IV_QUICKINFO_BUTTON_2       = ' '
  866.     importing
  867.       answer                      = lv_ans
  868. *   TABLES
  869. *     PARAMETER                   =
  870.     exceptions
  871.       others                      = 1.
  872.  
  873.   if sy-subrc <> 0.
  874.     message id sy-msgid type sy-msgty number sy-msgno
  875.        with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  876.   endif.
  877.  
  878.   if lv_ans <> '1'.
  879.     message s000(clhp) with 'Загрузка отменена пользователем'(024).
  880.     return.
  881.   endif.
  882.  
  883.   call function 'POPUP_TO_CONFIRM'
  884.     exporting
  885. *     TITLEBAR                    = ' '
  886. *     DIAGNOSE_OBJECT             = ' '
  887.       text_question               = 'Хотите ли вы посмотреть список загружаемых таблиц?'(025)
  888. *     TEXT_BUTTON_1               = 'Ja'(001)
  889. *     ICON_BUTTON_1               = ' '
  890. *     TEXT_BUTTON_2               = 'Nein'(002)
  891. *     ICON_BUTTON_2               = ' '
  892. *     DEFAULT_BUTTON              = '1'
  893. *     DISPLAY_CANCEL_BUTTON       = 'X'
  894. *     USERDEFINED_F1_HELP         = ' '
  895. *     START_COLUMN                = 25
  896. *     START_ROW                   = 6
  897. *     POPUP_TYPE                  =
  898. *     IV_QUICKINFO_BUTTON_1       = ' '
  899. *     IV_QUICKINFO_BUTTON_2       = ' '
  900.     importing
  901.       answer                      = lv_ans
  902. *   TABLES
  903. *     PARAMETER                   =
  904.     exceptions
  905.       others                      = 1.
  906.  
  907.   if sy-subrc <> 0.
  908.     message id sy-msgid type sy-msgty number sy-msgno
  909.        with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  910.   endif.
  911.  
  912.   if lv_ans = '1'.
  913.  
  914.     call function 'POPUP_WITH_TABLE'
  915.       exporting
  916.         endpos_col   = 50
  917.         endpos_row   = 30
  918.         startpos_col = 10
  919.         startpos_row = 10
  920.         titletext    = 'Список загружаемых таблиц'(026)
  921.       tables
  922.         valuetab     = lt_names[]
  923.       exceptions
  924.         break_off    = 1
  925.         others       = 2.
  926.  
  927.     if sy-subrc <> 0 and sy-subrc <> 1.
  928.       message id sy-msgid type sy-msgty number sy-msgno
  929.         with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  930.     endif.
  931.   endif.
  932.  
  933. * Perform load
  934.   loop at lt_names into lv_name.
  935.  
  936.     concatenate 'Загрузка данных таблицы'(027) lv_name into lv_text separated by space.
  937.     perform statusbar_message using 0 lv_text.
  938.  
  939.     perform modify_dbtab_from_file
  940.                 using
  941.                    lv_name
  942.                    lt_contents[]
  943.                    p_del
  944.                 changing
  945.                    lv_rc.
  946.  
  947.     if lv_rc <> 0.
  948.       rollback work.                                   "#EC CI_ROLLBACK
  949.       perform log_msg changing lt_log[].
  950.       perform show_log using lt_log[].
  951.       return.
  952.     endif.
  953.   endloop.
  954.  
  955.   commit work.
  956.  
  957.   lv_text = lv_lines.
  958.   condense lv_text.
  959.   message i000(clhp) with 'Содержимое'(028) lv_text 'таблиц успешно загружено'(029).
  960. endform.                    " main_import
  961. *&---------------------------------------------------------------------*
  962. *&      Form  show_log
  963. *&---------------------------------------------------------------------*
  964. *       Показывает лог на экран
  965. *----------------------------------------------------------------------*
  966. *  -->  p1        text
  967. *  <--  p2        text
  968. *----------------------------------------------------------------------*
  969. form show_log using ut_log  type bapiret2_t.
  970.  
  971.   call function 'SUSR_DISPLAY_LOG'
  972.     exporting
  973.       display_in_popup           = abap_true
  974.       log_title                  = 'Журнал обработки программы'(030)
  975.     tables
  976. *     IT_LOG_SPROT               =
  977.       it_log_bapiret2            = ut_log[]
  978.     exceptions
  979.       others                     = 1.
  980.  
  981.   if sy-subrc <> 0.
  982.     message id sy-msgid type sy-msgty number sy-msgno
  983.       with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  984.   endif.
  985. endform.                    " show_log
  986.  
  987. *&---------------------------------------------------------------------*
  988. *&      Form  statusbar_message
  989. *&---------------------------------------------------------------------*
  990. *       text
  991. *----------------------------------------------------------------------*
  992. *      -->UD_PERCENT text
  993. *      -->UD_TEXT    text
  994. *----------------------------------------------------------------------*
  995. form statusbar_message using ud_percent ud_text.
  996.   call function 'SAPGUI_PROGRESS_INDICATOR'
  997.     exporting
  998.       percentage = ud_percent
  999.       text       = ud_text.
  1000. endform.                    "statusbar_message
  1001.  
  1002. *&---------------------------------------------------------------------*
  1003. *&      Form  msg_to_ret2_string
  1004. *&---------------------------------------------------------------------*
  1005. *       text
  1006. *----------------------------------------------------------------------*
  1007. *      -->I_MESSAGE_TEXT  text
  1008. *      -->VALUE(I_MSGTY)  text
  1009. *      -->CT_RETURN       text
  1010. *----------------------------------------------------------------------*
  1011. form msg_to_ret2_string using i_message_text
  1012.                               value(i_msgty) type symsgty
  1013.                         changing ct_return  type bapiret2_t.
  1014.  
  1015.   data: ls_msg      type symsg,
  1016.         lv_len      type i,
  1017.         lv_dummy    type bapiret2-message.
  1018.  
  1019.   if i_msgty <> 'I'
  1020.     and i_msgty <> 'S'
  1021.     and i_msgty <> 'W'
  1022.     and i_msgty <> 'E'
  1023.     and i_msgty <> 'A'
  1024.     and i_msgty <> 'X'.
  1025.  
  1026.     i_msgty = 'S'.
  1027.   endif.
  1028.  
  1029.   ls_msg-msgid = 'CLHP'.
  1030.   ls_msg-msgno = '000'.
  1031.   ls_msg-msgty = i_msgty.
  1032.  
  1033.   lv_len = strlen( i_message_text ).
  1034.   if lv_len <= 50.
  1035.     ls_msg-msgv1 = i_message_text.
  1036.   endif.
  1037.   if lv_len > 50 and lv_len <= 100.
  1038.     ls_msg-msgv1 = i_message_text(50).
  1039.     ls_msg-msgv2 = i_message_text+50.
  1040.   endif.
  1041.   if lv_len > 100 and lv_len <= 150.
  1042.     ls_msg-msgv1 = i_message_text(50).
  1043.     ls_msg-msgv2 = i_message_text+50(50).
  1044.     ls_msg-msgv3 = i_message_text+100.
  1045.   endif.
  1046.   if lv_len > 150.
  1047.     ls_msg-msgv1 = i_message_text(50).
  1048.     ls_msg-msgv2 = i_message_text+50(50).
  1049.     ls_msg-msgv3 = i_message_text+100(50).
  1050.     ls_msg-msgv4 = i_message_text+150.
  1051.   endif.
  1052.  
  1053.   message id ls_msg-msgid type ls_msg-msgty number ls_msg-msgno
  1054.     with ls_msg-msgv1 ls_msg-msgv2 ls_msg-msgv3 ls_msg-msgv4 into lv_dummy.
  1055.  
  1056.   perform log_msg changing ct_return[].
  1057. endform.                    "msg_to_ret2_string
  1058.  
  1059. *&---------------------------------------------------------------------*
  1060. *&      Form  log_msg
  1061. *&---------------------------------------------------------------------*
  1062. *       text
  1063. *----------------------------------------------------------------------*
  1064. *      -->CT_RETURN  text
  1065. *----------------------------------------------------------------------*
  1066. form log_msg changing ct_return      type bapiret2_t.
  1067.  
  1068.   field-symbols: <ls_return>    type bapiret2.
  1069.  
  1070.   append initial line to ct_return assigning <ls_return>.
  1071.   <ls_return>-id         = sy-msgid.
  1072.   <ls_return>-number     = sy-msgno.
  1073.   <ls_return>-type       = sy-msgty.
  1074.   <ls_return>-message_v1 = sy-msgv1.
  1075.   <ls_return>-message_v2 = sy-msgv2.
  1076.   <ls_return>-message_v3 = sy-msgv3.
  1077.   <ls_return>-message_v4 = sy-msgv4.
  1078. endform.                    "log_msg
inikolax  Черкашин Николай  ENRC BTS